mirror of
https://codeberg.org/ziglang/zig.git
synced 2025-12-06 13:54:21 +00:00
58edefc6d1
Rework std.Build.Step to have an `owner: *Build` field. This simplified the implementation of installation steps, as well as provided some much-needed common API for the new parallelized build system. --verbose is now defined very concretely: it prints to stderr just before spawning a child process. Child process execution is updated to conform to the new parallel-friendly make() function semantics. DRY up the failWithCacheError handling code. It now integrates properly with the step graph instead of incorrectly dumping to stderr and calling process exit. In the main CLI, fix `zig fmt` crash when there are no errors and stdin is used. Deleted steps: * EmulatableRunStep - this entire thing can be removed in favor of a flag added to std.Build.RunStep called `skip_foreign_checks`. * LogStep - this doesn't really fit with a multi-threaded build runner and is effectively superseded by the new build summary output. build runner: * add -fsummary and -fno-summary to override the default behavior, which is to print a summary if any of the build steps fail. * print the dep prefix when emitting error messages for steps. std.Build.FmtStep: * This step now supports exclude paths as well as a check flag. * The check flag decides between two modes, modify mode, and check mode. These can be used to update source files in place, or to fail the build, respectively. Zig's own build.zig: * The `test-fmt` step will do all the `zig fmt` checking that we expect to be done. Since the `test` step depends on this one, we can simply remove the explicit call to `zig fmt` in the CI. * The new `fmt` step will actually perform `zig fmt` and update source files in place. std.Build.RunStep: * expose max_stdio_size is a field (previously an unchangeable hard-coded value). * rework the API. Instead of configuring each stream independently, there is a `stdio` field where you can choose between `infer_from_args`, `inherit`, or `check`. These determine whether the RunStep is considered to have side-effects or not. The previous field, `condition` is gone. * when stdio mode is set to `check` there is a slice of any number of checks to make, which include things like exit code, stderr matching, or stdout matching. * remove the ill-defined `print` field. * when adding an output arg, it takes the opportunity to give itself a better name. * The flag `skip_foreign_checks` is added. If this is true, a RunStep which is configured to check the output of the executed binary will not fail the build if the binary cannot be executed due to being for a foreign binary to the host system which is running the build graph. Command-line arguments such as -fqemu and -fwasmtime may affect whether a binary is detected as foreign, as well as system configuration such as Rosetta (macOS) and binfmt_misc (Linux). - This makes EmulatableRunStep no longer needed. * Fix the child process handling to properly integrate with the new bulid API and to avoid deadlocks in stdout/stderr streams by polling if necessary. std.Build.RemoveDirStep now uses the open build_root directory handle instead of an absolute path.
96 lines
3.5 KiB
Zig
96 lines
3.5 KiB
Zig
const std = @import("../std.zig");
|
|
const mem = std.mem;
|
|
const fs = std.fs;
|
|
const Step = std.Build.Step;
|
|
const InstallDir = std.Build.InstallDir;
|
|
const InstallDirStep = @This();
|
|
const log = std.log;
|
|
|
|
step: Step,
|
|
options: Options,
|
|
/// This is used by the build system when a file being installed comes from one
|
|
/// package but is being installed by another.
|
|
dest_builder: *std.Build,
|
|
|
|
pub const base_id = .install_dir;
|
|
|
|
pub const Options = struct {
|
|
source_dir: []const u8,
|
|
install_dir: InstallDir,
|
|
install_subdir: []const u8,
|
|
/// File paths which end in any of these suffixes will be excluded
|
|
/// from being installed.
|
|
exclude_extensions: []const []const u8 = &.{},
|
|
/// File paths which end in any of these suffixes will result in
|
|
/// empty files being installed. This is mainly intended for large
|
|
/// test.zig files in order to prevent needless installation bloat.
|
|
/// However if the files were not present at all, then
|
|
/// `@import("test.zig")` would be a compile error.
|
|
blank_extensions: []const []const u8 = &.{},
|
|
|
|
fn dupe(self: Options, b: *std.Build) Options {
|
|
return .{
|
|
.source_dir = b.dupe(self.source_dir),
|
|
.install_dir = self.install_dir.dupe(b),
|
|
.install_subdir = b.dupe(self.install_subdir),
|
|
.exclude_extensions = b.dupeStrings(self.exclude_extensions),
|
|
.blank_extensions = b.dupeStrings(self.blank_extensions),
|
|
};
|
|
}
|
|
};
|
|
|
|
pub fn init(owner: *std.Build, options: Options) InstallDirStep {
|
|
owner.pushInstalledFile(options.install_dir, options.install_subdir);
|
|
return .{
|
|
.step = Step.init(.{
|
|
.id = .install_dir,
|
|
.name = owner.fmt("install {s}/", .{options.source_dir}),
|
|
.owner = owner,
|
|
.makeFn = make,
|
|
}),
|
|
.options = options.dupe(owner),
|
|
.dest_builder = owner,
|
|
};
|
|
}
|
|
|
|
fn make(step: *Step, prog_node: *std.Progress.Node) !void {
|
|
_ = prog_node;
|
|
const self = @fieldParentPtr(InstallDirStep, "step", step);
|
|
const dest_builder = self.dest_builder;
|
|
const dest_prefix = dest_builder.getInstallPath(self.options.install_dir, self.options.install_subdir);
|
|
const src_builder = self.step.owner;
|
|
const full_src_dir = src_builder.pathFromRoot(self.options.source_dir);
|
|
var src_dir = std.fs.cwd().openIterableDir(full_src_dir, .{}) catch |err| {
|
|
log.err("InstallDirStep: unable to open source directory '{s}': {s}", .{
|
|
full_src_dir, @errorName(err),
|
|
});
|
|
return error.StepFailed;
|
|
};
|
|
defer src_dir.close();
|
|
var it = try src_dir.walk(dest_builder.allocator);
|
|
next_entry: while (try it.next()) |entry| {
|
|
for (self.options.exclude_extensions) |ext| {
|
|
if (mem.endsWith(u8, entry.path, ext)) {
|
|
continue :next_entry;
|
|
}
|
|
}
|
|
|
|
const full_path = dest_builder.pathJoin(&.{ full_src_dir, entry.path });
|
|
const dest_path = dest_builder.pathJoin(&.{ dest_prefix, entry.path });
|
|
|
|
switch (entry.kind) {
|
|
.Directory => try fs.cwd().makePath(dest_path),
|
|
.File => {
|
|
for (self.options.blank_extensions) |ext| {
|
|
if (mem.endsWith(u8, entry.path, ext)) {
|
|
try dest_builder.truncateFile(dest_path);
|
|
continue :next_entry;
|
|
}
|
|
}
|
|
|
|
try dest_builder.updateFile(full_path, dest_path);
|
|
},
|
|
else => continue,
|
|
}
|
|
}
|
|
}
|